// Imports the GIFEndocer class by Thibault Imbert.
// You can download it from ByteArray.org.
import org.gif.encoder.GIFEncoder;
 
var serverPath:String = "/";
 
// Initializes GIFEncoder
var myGIFEncoder:GIFEncoder = new GIFEncoder();
myGIFEncoder.setRepeat(0);
myGIFEncoder.setDelay (300);
 
// Initializes an URLLoader object to upload a file stream.
var ul:URLLoader = new URLLoader();
ul.addEventListener(Event.COMPLETE, saveDone);
 
var urh:URLRequestHeader = new URLRequestHeader("Accept","image/gif");
var BOUNDARY:String = "---------------------------7d76d1b56035e";
 
/**
 * Starts the gif encoding when clicks on the stage.
 */
stage.addEventListener(MouseEvent.CLICK, generateGIF);
function generateGIF(evt:MouseEvent):void{
 
	// Starts the gif encoder.
	myGIFEncoder.start();
 
	// Add frame.
	var bd:BitmapData = new BitmapData(100, 100, false, Math.round(0xFFFFFF*Math.random()));
	myGIFEncoder.addFrame(bd);
 
	// Finishes the gif encoder.
	myGIFEncoder.finish();
 
	// Starts the upload process.
	uploadGIF();
 
}// end generateGIF
 
/**
 * Generates a file stream and upload it.
 */
function uploadGIF():void{
 
	// Retrieves the file stream from the GIF Encoder.
	var myGIFStream:ByteArray = myGIFEncoder.stream;
	var filename:String = "test.gif";
 
	// Creates the file header.
	var formData:String  =  "--" + BOUNDARY + '\r\nContent-Disposition: form-data; name="Filedata"; filename="' + filename + '"\r\nContent-Type: application/octet-stream\r\n\r\n';
	var formData2:String = "\r\n";
	formData2 += "--" + BOUNDARY + '\r\nContent-Disposition: form-data; name="Filedata"\r\n\r\nSubmit Query\r\n';
	formData2 += "--" + BOUNDARY + '--';
 
 
	// Conbines the header and the file stream.
	var dataArray:ByteArray = new ByteArray();
	dataArray.writeMultiByte(formData,"ascii");
	for(var k:uint=0; k<myGIFStream.length; k++){
		dataArray.writeByte(myGIFStream[k]);
	}	
	dataArray.writeMultiByte(formData2,"ascii");
 
	// Initializes an URLRequest object
	var ur:URLRequest = new URLRequest();
	ur.requestHeaders.push(urh);
	ur.method = URLRequestMethod.POST;
	ur.contentType = "multipart/form-data; boundary=" + BOUNDARY;
	ur.url = serverPath + "test/uploadok.php";
	ur.data = dataArray;
 
	ul.load(ur);
 
}// end uploadGIF
 
/**
 * Executes when a file upload is finished.
 */
function saveDone(evt:Event):void{
	var str:String = evt.target.data;
	trace(str);
}// end saveDone

var serverPath:String = "/";
 
// Creates a FileReference object.
var fr:FileReference = new FileReference();
var frFilter:FileFilter = new FileFilter("JPGs", "*.jpg");
 
// Adds events to the FileReference object.
fr.addEventListener(Event.SELECT, fileSelected);
fr.addEventListener(DataEvent.UPLOAD_COMPLETE_DATA, fileUploaded);
fr.addEventListener(ProgressEvent.PROGRESS, fileProgress);
fr.addEventListener(IOErrorEvent.IO_ERROR, errorOccured);
 
 
/**
 * Executes when a user selects a file to upload.
 */
function fileSelected(evt:Event):void{
 
	// Checks the size of the file.
	if(fr.size > 200*1024){
		trace("You can NOT upload an image lagerer than 200KB.");
	}else{
		var ur:URLRequest = new URLRequest();
		ur.url = serverPath + "test/uploadok.php";
 
		// Puts newName parameter, to avoid the multi-byte filename problem.
		var uv:URLVariables = new URLVariables();
		uv.newName = "upload.jpg";
 
		ur.data = uv;
 
		// Starts uploading.
		fr.upload(ur);
	}// end if else [fr.size]
 
}// end fileSelected
 
 
/**
 * Executes when a file upload is finished.
 */
function fileUploaded(evt:DataEvent):void{
	trace(evt.data);
}// end fileUploaded
 
/**
 * Executes while uploading a file.
 */
function fileProgress(evt:ProgressEvent):void{
	//trace(evt.bytesLoaded + " / " + evt.bytesTotal);
}// end fileProgress
 
/**
 * Executes when an IO error occurs.
 */
function errorOccured(evt:IOErrorEvent):void{
	trace("IO error has occured.");
}// end errorOccured
 
 
/**
 * Shows the file browser when clicks on the stage.
 */
stage.addEventListener(MouseEvent.MOUSE_DOWN, clicked);
function clicked(evt:MouseEvent):void{
	fr.browse([frFilter]);
}

var uv:URLVariables = new URLVariables();
uv.newName = "upload.jpg";
 
ur.data = uv;

<?
/**
 * uploadok.php
 * ------------
 * Author: Han Sanghun (http://hangunsworld.com, hanguns@gmail.com)
 *       Kim Eung (http://eung.co.kr/)
 * Release Version: 1.0.0
 * Date Started: 2007/04/01
 * Last Modified: 2008/01/04
 *
 * Determines the name of the saved file.
 * If "newName" is provided, then uses "newName" as the file's name.
 * Otherwise, uses the original filename("Filedata.name") as the filename.
 *
 * If the original name of the file contains 2-byte characters (e.g. Korean characters), IO error occurs.
 * To avoid this, use "newName" parameter defined in Flash, rather than the "Filedata.name".
 * It is possible to assigns a new name in PHP code explicitly.
 */
 
$newName = trim($_REQUEST["newName"]);
if($newName == ""){
	// If newName is not defined, uses Filedata.name as the filename.
	$newName = $HTTP_POST_FILES['Filedata']['name'];
}
 
// Creates "images" folder, if not exist.
if(!is_dir("./images")){
	mkdir("./images",0777);
}
 
// Sets the path in which the uploaded image to be stored.
$folderPath = $_SERVER['DOCUMENT_ROOT']."/test/images/";
$newPath = $folderPath.$newName;
 
// Moves the temporary file.
@move_uploaded_file($HTTP_POST_FILES['Filedata']['tmp_name'], $newPath);
 
// Returns the saved file path.
echo "/test/images/".$newName;
?>